modules/main.nix


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65

{
  config,
  pkgs,
  lib,
  ...
}:
with builtins // lib;
{
  imports = [
    ./files.nix
  ];

  options = {
    koreader = {
      flavor = mkOption {
        type =
          with types;
          nullOr
          <| enum [
            "raw"
            "kobo"
            "pocketbook"
          ];
        default = null;
      };
      basePackage = mkOption {
        type = types.path;
      };
      koreaderPath = mkOption {
        type = types.str;
      };
      finalPackage = mkOption {
        type = types.package;
        readOnly = true;
        default = pkgs.runCommandLocal "merge" { nativeBuildInputs = [ pkgs.rsync ]; } ''
          RSYNC="rsync -a --copy-links -v"

          $RSYNC "${config.koreader.basePackage}/" "$out/"
          $RSYNC "${config._files}/" "$out/${config.koreaderPath}/"
        '';
      };
    };
  };

  config = mkMerge [
    (mkIf (config.koreader.flavor == "kobo") {
      koreader = {
        basePackage = mkOptionDefault <| pkgs.callPackage ../pkgs/kobo.nix { };
        koreaderPath = mkOptionDefault ".adds/koreader";
      };
    })
    (mkIf (config.koreader.flavor == "pocketbook") {
      koreader = {
        basePackage = mkOptionDefault <| pkgs.callPackage ../pkgs/pocketbook.nix { };
        koreaderPath = mkOptionDefault "applications/koreader";
      };
    })
    (mkIf (config.koreader.flavor == "raw") {
      koreader = {
        basePackage = mkOptionDefault <| pkgs.runCommandLocal "raw" { } "mkdir $out";
        koreaderPath = mkOptionDefault "";
      };
    })
  ];
}